Talk:The Coracle

General enter and exit messages:

@Osucc The Coracle=%N enters [name(%!)].

@Oxleave The Coracle=leaves [name(%!)].

@Oxenter The Coracle=enters [name(%!)].

General description messages. @idesc is what people inside the vehicle see and so should probably include a few more details than the @desc (what people outside the vehicle see).

&UMBRADESC The Coracle=%r%t(This room needs an Umbra desc. @mail [get(me/buildstaff)] if you want to provide one.)%r

&WRAITHDESC The Coracle=%r%t(This room needs a Wraith desc. @mail [get(me/buildstaff)] if you want to provide one.)%r

&FAEDESC The Coracle=%r%t(This room needs a Fae desc. @mail [get(me/buildstaff)] if you want to provide one.)%r

&MATRIXDESC The Coracle=%r%tThe net is vast and infinite, stretching far beyond the reaches of mankind's inferior means of technology. Here across the digital heavens of megabytes and electrical dreams. In a world of maddening webs and virtual freedom runs rampant a tyraid of the masses of multiple users encampassing what is known as the Digital Web.%r%r

@Idesc The Coracle=%r%tWhile far from the largest boat in Prospect's waters, at just under 75' in length the Coracle's name is something of a joke. Rather than being a small wicker boat barely large enough to hold a single person the Coracle is a 2019 Sunseeker Predator 74, a boat capable of taking 8 guests and a crew of 2 well beyond the horizon and back. Its primary limitation for deeper waters is its lack of fuel storage which gives it a maximum range of around 330 nautical miles (nearly 380 standard miles) and its limited supplies of food and water.%r%r%tWhile a flybridge is common on most boats of this size (and indeed, even older models of the Predator 74) this is not possible on this particular model. A large portion of the front glass canopy is capable of being slid back, much like the roof of a coupe, to open the cockpit to the air.%r%r%tA Williams Sportjet 395 is stored in the tender garage and the small crew cabin has been given over to the storage of scuba equipment. It isn't that the cabin has been remodeled with racks and storage installed but rather just that dive tanks, regulators, and flippers sit on the twin beds while most of the stowage has been filled with items such as wet suits, masks, weight belts, and other sundry but critical pieces of diving equipment.%r%r[center(<+views and +places are available>,79)]%r

@Desc The Coracle=%r%tWhile far from the largest boat in Prospect's waters, at just under 75' in length the Coracle's name is something of a joke. Rather than being a small wicker boat barely large enough to hold a single person the Coracle is a 2019 Sunseeker Predator 74, a boat capable of taking 8 guests and a crew of 2 well beyond the horizon and back. Its primary limitation for deeper waters is its lack of fuel storage which gives it a maximum range of around 330 nautical miles (nearly 380 standard miles) and its limited supplies of food and water.%r%r%tWhile a flybridge is common on most boats of this size (and indeed, even older models of the Predator 74) this is not possible in this instance. This is because a large portion of the front glass canopy is capable of being slid back, much like the roof of a coupe, to open the cockpit to the air.%r

Commands for operating the vehicle. Using @emit will cause a funny doubled message. @vemit can be used in its place and will not have that problem. While +sail look can be used to view the area outside the vehicle it will spam everyone inside with the message. +vlook can be used instead.

&CMD_VEHICLE The Coracle=$vehicle *:@if strmatch(%l,%!)=@force me=%0,@pemit %#=error()

&CMD_SAIL The Coracle=$+sail *:@if strmatch(%l,%!)=@force me=%0,@pemit %#=error()

&CMD_VLOCK The Coracle=$+vlock *:@if and(strmatch(num(%0),%!),strmatch(%#,owner(%!)))={@set %!=!enter_ok;@pemit %#=pcol(Locked.)}

&CMD_VUNLOCK The Coracle=$+vunlock *:@if and(strmatch(num(%0),%!),strmatch(%#,owner(%!)))={@set %!=!enter_ok;@pemit %#=pcol(Unlocked.)}

&CMD_VEMIT The Coracle=$@vemit *:@dolist lcon(me)=@pemit ##=%0

&VLOOK The Coracle=[moniker(here)]%r[u(here/desc)][switch(words(lcon(here)),1,,Contents:%r[edit(iter(lcon(here),switch(##,num(me),,moniker(##)%r)),%r%b,%r)])][ansi(y,Navigation:)]%r[iter(lexits(here),{%b%b%b[exitname([last(name(##),:)],[ucstr(first(name(##),:))])]})]%r

&CMD_VLOOK The Coracle=$+vlook:@pemit %#=u(me/vlook)

Code that will make some of the activity that takes place inside the vehicle visible to those outside. It ties to places code as the places can be used to determine when someone is in a location where they will be hidden to people outside. In this example places 1, 3, and 4 are visible to people outside while 2 and 5 are not. If you want to alter which places are visible and which are hidden replace the part of code that says 1 3 4 in @ahear with the locations that are not hidden.

@Listen The Coracle=*

@Ahear The Coracle=@switch [setq(1, U(WHICHPLACE, %#))][setq(0,U(GETINFO,r(1),NAME))][gt(match(1 3 4,[r(1)]),0)][gt(match(lcon(me),%#),0)]=1*,{@emit From the [lcstr(r(0))] of [edit(name(me),The%b,the%b)], %0},01,{@emit From [edit(name(me),The%b,the%b)], %0},@@

@Infilter The Coracle=From*[name(me)]*

@Inprefix The Coracle=Outside the boat,

&PLACESMAX The Coracle=5

&PLACESCLEANUP1 The Coracle=^* has left.:placescleanup(%#)

&PLACESCLEANUP2 The Coracle=^* has disconnected.:placescleanup(%#)

&PLACENUMS The Coracle=|||||

&PLACE1 The Coracle=Foredeck|6|6||I'm sorry, there's no room to add a place there.|I'm sorry, there's no place to move there.|You head to the|heads to the|You leave the|leaves the|On the foredeck|%r%tOn the bow of the boat sits a sunpad large enough for two people %(or three if they are very friendly%), a small table with folding top, and a C shaped padded bench.%r

&PLACE2 The Coracle=Cockpit|10|10||I'm sorry, there's no room to add a place there.|I'm sorry, there's no place to move there.|You head into the|heads into the|You leave the|leaves the|In the cockpit|%r%tThough it is called the cockpit only a small portion of this area is dedicated to controlling the ship. Immediately behind the twin bucket seats is an area roughly 15' x 15' with a padded cloth covered couch arranged surrounding on three sides a small table with a folding top along the starboard wall and a large screen tv along the port.%r%r%tThe boat lacks a flybridge because the front half of the cockpit is a retractable glass sunroof, capable of sliding back over the rest of the cockpit and opening the ship up to the sky. A small l-shaped seating area immediately to port of the control station is capable of seating three people.%r

&PLACE3 The Coracle=Deck Saloon|12|12||I'm sorry, there's no room to add a place there.|I'm sorry, there's no place to move there.|You head to the|heads to the|You leave the|leaves the|In the saloon|%r%tImmediately aft of the cockpit is the ship's saloon. It is roughly 15' x 25' and split into two area. It is more exposed to the elements than the sitting area within the cockpit though still somewhat shielded. The door and wall which separates the two can be retracted into the sole turning the two into one large area.%r%r%tThe saloon itself is separated into two areas. To the fore is an alfresco dining area. It consists of a vinyl covered bench which surrounds on three sides a table with a folding top that is set to the starboard while a small wetbar sits to port. Aft of the sitting area is a large sunpad that stretches the entire width of the area.%r

&PLACE4 The Coracle=Swimming Platform|5|5||I'm sorry, there's no room to add a place there.|I'm sorry, there's no place to move there.|You head to the|heads to the|You leave the|leaves the|On the swimming platform|%r%tAt the aft of the ship sits a hydraulic platform. Controls allow it to be raised clear of the water or lowered to slightly below the water level, allowing it to be used as a launch for a tender or jetski, or to simply make it easier for swimmers to reboard the boat.%r

&PLACE5 The Coracle=Below Decks|15|15||I'm sorry, there's no room to add a place there.|I'm sorry, there's no place to move there.|You head|heads|You leave|leaves|Below decks|%r%tBelow the ship is just as opulent as it is above with a double stateroom to the fore and a master stateroom aft. A third, guest stateroom sits to starboard and is capable of holding two people, albeit not in the spacious accommodations of the larger staterooms and in a pinch what is meant to be the crew cabin could accommodate two more individuals. Additionally there is a well sized galley and even a small dedicated wine cooler capable of holding two dozen bottles.%r%r%tWhile below deck can often be a somewhat dark affair large pillarless windows run along the sides of the Coracle, allowing in a generous amount of light and giving those in the cabins wonderful views of the ocean outside.%r

&WHICHPLACE The Coracle=[match(get(me/PLACENUMS), *%0*, |)]

&GETINFO The Coracle=[extract(get(me/PLACE%0),match(NAME MAXPLACES CURPLACES FIXED FULL EMPTY JOIN OJOIN DEPART ODEPART PREFIX PDESC,%1),1,|)]

&CMD_DEPART The Coracle=$depart:@switch [setq(1, U(WHICHPLACE, %#))][setq(0,U(GETINFO,r(1),NAME))][r(1)]=0, {@pemit %#=You aren't placed anywhere.}, {&PLACENUMS ME=[replace(get(ME/PLACENUMS), r(1), [remove(extract(get(ME/PLACENUMS), r(1), 1, |), %#)], |)];@pemit %#=[setq(2,U(me/GETINFO, r(1), DEPART))][setq(3,U(me/GETINFO, r(1), ODEPART))][r(2)] [r(0)];@pemit/list [edit(lcon(me),%#,)]=[moniker(%#)] [r(3)] [r(0)];@switch gt(match(1 3 4,[r(1)]),0)=1,{@emit From [name(me)], [moniker(%#)] [r(3)] [r(0)]}}

&VIEW-SPECIAL The Coracle=%rThis vehicle has several special commands and functions.%r%r@vemit%t%tThis option functions identically to @emit but does not produce%r%t%tthe "doubled" message that @emit produces inside vehicles.%r+sail <cmd>%tThis option forces the boat to execute <cmd>%r+vlook%t%tReturns what is outside the boat without spamming people within%r%t%tthe boat (which will occur if you use +sail look)%rplaces%t%tThe Coracle has been configured to take advantage of places%r%t%tcommands.%r%rCharacters sitting at locations 1, 3, or 4 (the foredeck, saloon, or swimming platform) who do not use the tt functions will have the message broadcast to anyone -*outside*- the vehicle (you're in open air in those locations).%r